Re: [sv-bc] SV-BC19-60 -- Proposal (A.1.4, A.1.5, A.1.6, A.2.6, A.2.7, 6-1, 10-1, 10-2, 17-1, 18-1)

Subject: Re: [sv-bc] SV-BC19-60 -- Proposal (A.1.4, A.1.5, A.1.6, A.2.6, A.2.7, 6-1, 10-1, 10-2, 17-1, 18-1)
From: Brad Pierce (Brad.Pierce@synopsys.com)
Date: Fri Feb 28 2003 - 17:59:43 PST

Dan,

Thanks for pointing this out. Apparently many of the changes made
by the SV-BC were not incorporated into the latest LRM draft.
Could you please make a friendly amendment to my proposal that
would make it consistent with the unincorporated changes?

The intent is to disallow interface_port_declaration as
module_item or interface_item.

Thanks again,

-- Brad

p.s. Is there a more up-to-date Annex A than the one in the
latest draft of the LRM?

-----Original Message-----
From: Jacobi, Dan [mailto:dan.jacobi@intel.com]
Sent: Friday, February 28, 2003 5:35 PM
To: Brad.Pierce@synopsys.COM; sv-bc@eda.org
Subject: RE: [sv-bc] SV-BC19-60 -- Proposal (A.1.4, A.1.5, A.1.6, A.2.6,
A.2.7, 6-1, 10-1, 10-2, 17-1, 18-1)

Brad,

The first part looks O.K. and I think it complies with my second proposal.
However the second part changes to A.2.6 and A.2.7, function and tasks
ports, are not aligned with the proposal we accepted to align the SVL BNF
with the IEEE 1364 (after ETF changes) BNF.
We accepted the use of tf ports in A.2.6 and A.2.7 (tf_input_declaration,
tf_output_declaration, etc ...)

Enjoy
Danny
-----Original Message-----
From: Brad Pierce [mailto:Brad.Pierce@synopsys.com]
Sent: Friday, February 28, 2003 7:18 PM
To: sv-bc@eda.org
Subject: [sv-bc] SV-BC19-60 -- Proposal (A.1.4, A.1.5, A.1.6, A.2.6, A.2.7,
6-1, 10-1, 10-2, 17-1, 18-1)

Proposal

---------------------------------------------------------------------------- 

----

In A.1.4, ADD the following nonterminal --

   non_interface_port_declaration ::=
         { attribute_instance } inout_declaration
       | { attribute_instance } input_declaration
       | { attribute_instance } output_declaration

and REPLACE

   port_declaration ::=
         { attribute_instance } inout_declaration
       | { attribute_instance } input_declaration
       | { attribute_instance } output_declaration
       | { attribute_instance } interface_port_declaration

WITH

   port_declaration ::=
         non_interface_port_declaration
       | { attribute_instance } interface_port_declaration

---

In A.1.5 and 17-1, REPLACE

   module_item ::=
         port_declaration ';'
       | non_port_module_item

WITH

   module_item ::=
         non_interface_port_declaration ';'
       | non_port_module_item

---

In A.1.6 6-1, and 18-1, REPLACE

   interface_item ::=
         port_declaration ';'
       | non_port_interface_item

WITH

   interface_item ::=
         non_interface_port_declaration ';'
       | non_port_interface_item

---

In A.2.6 and 10-2, REPLACE

   function_item_declaration ::=
         block_item_declaration
       | { attribute_instance } input_declaration ';'
       | { attribute_instance } output_declaration ';'
       | { attribute_instance } inout_declaration ';'

WITH

   function_item_declaration ::=
         block_item_declaration
       | non_interface_port_declaration ';'

and REPLACE

   function_port_item ::=
         { attribute_instance } input_declaration
       | { attribute_instance } output_declaration
       | { attribute_instance } inout_declaration

WITH

   function_port_item ::= non_interface_port_declaration

---

In A.2.7 and 10-1, REPLACE

   task_item_declaration ::=
         block_item_declaration
       | { attribute_instance } input_declaration ';'
       | { attribute_instance } output_declaration ';'
       | { attribute_instance } inout_declaration ';'

WITH

   task_item_declaration ::=
         block_item_declaration
       | non_interface_port_declaration ';'

and REPLACE

   task_port_item ::=
         { attribute_instance } input_declaration
       | { attribute_instance } output_declaration
       | { attribute_instance } inout_declaration
       | { attribute_instance } port_type list_of_port_identifiers

WITH

   task_port_item ::=
         non_interface_port_declaration
       | { attribute_instance } port_type list_of_port_identifiers

----------------------------------------------------------------------------
----

This archive was generated by hypermail 2b28 : Fri Feb 28 2003 - 18:00:29 PST